Arduino 自走車 & 機械手臂

-
微算機實驗課程期末專題有些人接線做 8051 喇叭，但因為器材不太夠，就有幾個人可以玩 Arduino 自走車，剛好 MOLi 實驗室有舉辦機械手臂相關活動也是使用 Arduino 去弄，就順便將這兩樣東西兜起來當作期末報告。

使用器材

  • Arduino UNO

  • Arduino Sensor Shield V5.0 感測器擴展板

  • 自走車相關零組件

  • PS2 副廠搖桿

組裝教學

自走車


基本上可以參考這篇，其中我拿到的零件比較不同的是馬達驅動模組，但一樣接上 IN1~IN4 當作訊號即可，因為另一邊有通電了。聽同學說有個跳線的地方，蓋子拔掉就不會通電了，這樣就得自己接電接地。對於擴充版不熟悉的話可以參考這篇。

搖桿

網路上很多接線圖，大部分都一樣，這邊就貼個我看的順眼的。

遇到的坑

馬達

一開始測試馬達，code 寫進去要他怎麼轉就怎麼轉，可是之後重接重寫就發現不會動了。先檢查程式，發現是忘了在最前面寫上 pinMode 指定 OUTPUT。後來還是不會動，從馬達開始接電測試，不管正轉逆轉都沒問題，再來是馬達驅動模組，螺絲重新鎖、接電測試也都沒問題，那該不會是我的腦袋有問題吧!?最後終於發現是杜邦線太鬆、或是模組的針腳太細，總之就是接觸不良，因為這批線是當天助教拿新的給我，沒想到就有這個問題。後來詢問老師，說可能是針腳太短，且杜邦線價格差異很大，品質可能也有差。

PS2 搖桿

沒想到這搖桿也能拿來接 Arduino，上網找來找去好像就 PS2X 這個 Library 最好用，基本上就是範例 code 貼上去就要會動，可是我怎麼測試就是不會動，弄了約 3.4 小時聽到同學早就成功了，跟他借線測試後才知道可能有些訊號線斷掉了，之前還有請老師幫忙找問題，可惜沒找到，老師表示原來杜邦線品質這麼差。之後弄弄手臂再回來弄搖桿發現又不會動了。。。換線過後又正常，Arduino 這東西怎麼那麼難搞阿，光是接線測試就花了 8 小時，雖然很倒楣線材總是出包，但也只能怪自己沒玩過多少硬體，對於 debug 不熟悉。

IDE 問題

  • 在 Mac 上如果輸入法是在內建的注音模式，複製貼上或是快捷鍵註解等操錯可能會有問題，建議切換到英文模式操作。

  • 如果 Arduino 同時接電又接 USB，傳輸時可能會出現 stk500_recv(): programmer is not responding 錯誤，只要將電源拔掉即可

DEMO 影片


因為是一手操控搖桿一手攝影，稍微晃動

[video width="360" height="480" mp4="https://jackkuo.org/wp-content/uploads/2018/06/20180626_102720.mp4"][/video]

程式碼


#include <PS2X_lib.h> //for v1.6
#include <Servo.h>
#define LEFT_FORWARD 6
#define LEFT_BACKWARD 7
#define RIGHT_FORWARD 9
#define RIGHT_BACKWARD 8
#define MIDDLE_VALUE 127
#define CLAW 5
#define BASE 2
#define LEFT_ARM 3
#define RIGHT_ARM 4

PS2X ps2x;

int error = 0;
byte type = 0;
// 手把是否要震動
byte vibrate = 0;
// 總共有幾顆伺服馬達
const int SERVOS = 4;
// 類比搖桿至少扳動多少才開始動作
const int sensityOffset = 50;
Servo myservo[SERVOS];
int servoConfig[SERVOS][5] = {
        // Order, servoPin, minAngle, maxAngle, initialAngle
        {0, CLAW, 0, 50, 50},        // 夾子
        {1, BASE, 60, 140, 90},      // 基座
        {2, LEFT_ARM, 0, 70, 0},     // 左臂
        {3, RIGHT_ARM, 40, 110, 80}  // 右臂
    };
void setup() {
    Serial.begin(57600);
    pinMode(LEFT_FORWARD, OUTPUT);
    pinMode(LEFT_BACKWARD, OUTPUT);
    pinMode(RIGHT_FORWARD, OUTPUT);
    pinMode(RIGHT_BACKWARD, OUTPUT);
    error = ps2x.config_gamepad(13, 11, 10, 12, true, true); //setup pins and settings:  GamePad(clock, command, attention, data, Pressures?, Rumble?) check for error

    if (error == 0) {
        Serial.println("Found Controller, configured successful");
        Serial.println("Try out all the buttons, X will vibrate the controller, faster as you press harder;");
        Serial.println("holding L1 or R1 will print out the analog stick values.");
        Serial.println("Go to [url]www.billporter.info[/url] for updates and to report bugs.");
    } else if (error == 1)
        Serial.println("No controller found, check wiring, see readme.txt to enable debug. visit [url]www.billporter.info[/url] for troubleshooting tips");

    else if (error == 2)
        Serial.println("Controller found but not accepting commands. see readme.txt to enable debug. Visit [url]www.billporter.info[/url] for troubleshooting tips");

    else if (error == 3)
        Serial.println("Controller refusing to enter Pressures mode, may not support it. ");

    type = ps2x.readType();
    switch (type) {
    case 0:
        Serial.println("Unknown Controller type");
        break;
    case 1:
        Serial.println("DualShock Controller Found");
        break;
    case 2:
        Serial.println("GuitarHero Controller Found");
        break;
    }
    // 馬達初始化
    for(int i = 0; i < SERVOS; i++) {
        myservo[i].attach(servoConfig[i][1]);
        myservo[i].write(servoConfig[i][4]);
    }
}

void forward(){
    digitalWrite(LEFT_FORWARD, HIGH);
    digitalWrite(LEFT_BACKWARD, LOW);
    digitalWrite(RIGHT_FORWARD, HIGH);
    digitalWrite(RIGHT_BACKWARD, LOW);
}

void left(){
    digitalWrite(LEFT_FORWARD,LOW);
    digitalWrite(LEFT_BACKWARD,LOW);
    digitalWrite(RIGHT_FORWARD,HIGH);
    digitalWrite(RIGHT_BACKWARD,LOW);
}

void right(){
    digitalWrite(LEFT_FORWARD,HIGH);
    digitalWrite(LEFT_BACKWARD,LOW);
    digitalWrite(RIGHT_FORWARD,LOW);
    digitalWrite(RIGHT_BACKWARD,LOW);
}

void backward(){
    digitalWrite(LEFT_FORWARD, LOW);
    digitalWrite(LEFT_BACKWARD, HIGH);
    digitalWrite(RIGHT_FORWARD, LOW);
    digitalWrite(RIGHT_BACKWARD, HIGH);
}
void loop() {
    boolean shouldMove = false;
    int currentAngle[SERVOS];
    if (error == 1) //skip loop if no controller found
        return;

        //DualShock Controller

        ps2x.read_gamepad(false, vibrate); //read controller and set large motor to spin at 'vibrate' speed

        // 前進
        if (ps2x.Button(PSB_PAD_UP)) { //will be TRUE as long as button is pressed
            Serial.print("Up held this hard: ");
            Serial.println(ps2x.Analog(PSAB_PAD_UP), DEC);
            forward();
        }

        // 右轉
        if (ps2x.Button(PSB_PAD_RIGHT)) {
            Serial.print("Right held this hard: ");
            Serial.println(ps2x.Analog(PSAB_PAD_RIGHT), DEC);
            right();
        }

        // 左轉
        if (ps2x.Button(PSB_PAD_LEFT)) {
            Serial.print("LEFT held this hard: ");
            Serial.println(ps2x.Analog(PSAB_PAD_LEFT), DEC);
            left();
        }

        // 後退
        if (ps2x.Button(PSB_PAD_DOWN)) {
            Serial.print("DOWN held this hard: ");
            Serial.println(ps2x.Analog(PSAB_PAD_DOWN), DEC);
            backward();
        }

        if (ps2x.ButtonPressed(PSB_RED)) // will be TRUE if button was JUST pressed
            Serial.println("Circle just pressed");

        if (ps2x.ButtonReleased(PSB_PINK)) // will be TRUE if button was JUST released
            Serial.println("Square just released");

        if (ps2x.Button(PSB_L1) || ps2x.Button(PSB_R1)) // print stick values if either is TRUE
        {
            // Serial.print("Stick Values:");
            // Serial.print(ps2x.Analog(PSS_LY), DEC); //Left stick, Y axis. Other options: LX, RY, RX  
            // Serial.print(",");
            // Serial.print(ps2x.Analog(PSS_LX), DEC);
            // Serial.print(",");
            // Serial.print(ps2x.Analog(PSS_RY), DEC);
            // Serial.print(",");
            // Serial.println(ps2x.Analog(PSS_RX), DEC);

            // 以下為手臂移動
            currentAngle[0] = myservo[0].read();
            currentAngle[1] = myservo[1].read();
            currentAngle[2] = myservo[2].read();
            currentAngle[3] = myservo[3].read();
            // 左右移動計算
            if(ps2x.Analog(PSS_LX) < (MIDDLE_VALUE - sensityOffset) ) {
                if(currentAngle[1] < servoConfig[1][3]) {
                    currentAngle[1] += 2;
                    shouldMove = true;
                    // Serial.println(currentAngle[1]);
                }
             }
            else if(ps2x.Analog(PSS_LX) > (MIDDLE_VALUE + sensityOffset) ){
                if(currentAngle[1] > servoConfig[1][2]) {
                    currentAngle[1] -= 2;
                    shouldMove = true;
                    // Serial.println(currentAngle[1]);
                }
            }
            // 左臂計算
            if(ps2x.Analog(PSS_LY) < (MIDDLE_VALUE - sensityOffset) ) {
                if(currentAngle[2] < servoConfig[2][3]) {
                    currentAngle[2] += 2;
                    shouldMove = true;
                    // Serial.println(currentAngle[2]);
                }
            }
            else if(ps2x.Analog(PSS_LY) > (MIDDLE_VALUE + sensityOffset) ){
                if(currentAngle[2] > servoConfig[2][2]) {
                    currentAngle[2] -= 2;
                    shouldMove = true;
                    // Serial.println(currentAngle[2]);
                }
            }
            // 右臂計算
            if(ps2x.Analog(PSS_RY) < (MIDDLE_VALUE - sensityOffset) ) {
                if(currentAngle[3] < servoConfig[3][3]) {
                    currentAngle[3] += 2;
                    shouldMove = true;
                    // Serial.println(currentAngle[3]);
                }
            }
            else if(ps2x.Analog(PSS_RY) > (MIDDLE_VALUE + sensityOffset) ){
                if(currentAngle[3] > servoConfig[3][2]) {
                    currentAngle[3] -= 2;
                    shouldMove = true;
                    // Serial.println(currentAngle[3]);
                }
            }
            // 夾子
            if (ps2x.ButtonPressed(PSB_BLUE)){//will be TRUE if button was JUST pressed OR released
                Serial.println("X just changed");
                // Serial.println(currentAngle[0]);
                if(currentAngle[0] == servoConfig[0][2]){
                    currentAngle[0] = servoConfig[0][3];
                    shouldMove = true;
                    // Serial.println(currentAngle[0]);
                }
                else{
                    currentAngle[0] = servoConfig[0][2];
                    shouldMove = true;
                    // Serial.println(currentAngle[0]);
                }
            } 
            // 開始移動
            if(shouldMove) {
                myservo[0].write(currentAngle[0]);
                myservo[1].write(currentAngle[1]);
                myservo[2].write(currentAngle[2]);
                myservo[3].write(currentAngle[3]);
            }
        }

    delay(50);
    // 強制歸零，不然會一直跑
    digitalWrite(LEFT_FORWARD,HIGH);
    digitalWrite(LEFT_BACKWARD,HIGH);
    digitalWrite(RIGHT_FORWARD,HIGH);
    digitalWrite(RIGHT_BACKWARD,HIGH);
}

留言

張貼留言

這個網誌中的熱門文章

[Weekly Report] 2018.04.05 - 04.18

-
[Weekly Report] 2018.04.05 - 04.18 My dormitory doesn't have static public IP address so I tend to use Dynamic DNS (DDNS) method. Even though my D-Link Access Point (AP) provides free DDNS service, but I want to use my own domain name. First I change my domain name server from freenom to Cloudflare , then install ddclient for automatically update my IP address to Cloudflare. But no matter how I changed the arguments of the configuration file for hours, it still didn't work. Then I tended to use Cloudflare API and read the official document, it succeeded in ten minutes. Here is my sample DNS-update code, you can also use requests library instead of curl : '''This program will get record from Cloudflare and compare my current IP address''' import json from os import popen, system getCMD = 'curl -X GET "https://api.cloudflare.com/client/v4/zones/{ZONE-ID}/dns_records?type=A&name={YOUR-FULL-DOMAIN-NAME}" \ -H "X-Auth-Email: {YOUR-...
閱讀完整內容

LINE Notify 初嚐心得

-
圖片
因為「[MOLiの暨大最新公告❤️](https://t.me/ncnu_news)」這個暨大公告推播只有在 Telegram Channel 上面，一直沒有人弄到 LINE 上面，原以為是有什麼考量，一問之下才知道是原開發者懶得弄而已。 其實早在一兩年前我就想弄了，只是當時對 LINE 很反感，加上 LINE Bot 要錢就沒有嘗試，直到昨天看到一篇文章「[Ptt Alertor Ptt新文章即時通知](https://www.ptt.cc/bbs/EZsoft/M.1497363598.A.74E.html)」裡面提到使用 LINE Notify 可以無限次數推播（LINE Bot 只能回覆，主動推播要💰），這下我就心動了，當天晚上心血來潮使用 Django 測試了一下，果然沒什麼問題，就馬上著手進行開發。 [專案請點我](https://github.com/MOLi-rocks/MOLi-TelegramBot/)，或是看看我怎麼寫的朋友 [Commit History 在此](https://github.com/MOLi-rocks/MOLi-TelegramBot/commit/db8e815de3f53cfaea5ff45ddc4dad5b7841f36e)。 ## 著手進行 [LINE Notify 官方文件](https://notify-bot.line.me/doc/en/)排版有點糟，不過內容也不多，花幾分鐘看完就可以得知所有功能了。 ### 次數限制 其中，在最下方寫著「There is a limit to the number of times an API can be called on each service. The default number is set to 1000. The limit is per access token.」，上面又有個 [API Reference](https://developers.line.biz/en/enterprise-reference/messaging-api/#sending_message) 寫著每分鐘可以進行 1000 次 API call。以我破英文的理解能力，應該就是每分鐘不要觸發超過 1000 次就沒問題了，且在每次呼叫後，會在 Header...
閱讀完整內容

DokuWiki - Wiki 平台初體驗

-
你知道嗎？Wiki 並不是指維基百科，那是 Wikipedia，Wiki 其實是只說在網路上開放給大家多人協同創作的平台。 最近幫學生會弄了一個 Wiki 站，因此也稍微查了一下主流的 Wiki 平台。目前以 MediaWiki 為最多人使用，其次則是這篇所介紹的 DokuWiki。 那為什麼我選擇這套呢？網路上最近的評價是以 DokuWiki 為最好，也許是因為他的簡潔、權限控管功能、免資料庫而大受好評。對，你沒聽錯就是 不需要資料庫 ，跟 SPHINX 一樣不需要資料庫即可做到寫作、搜尋等功能。我在意的點除了免資料庫在部署上會比較容易，再來是有 Markdown 相關 plugin，Markdown 最近很紅，紅到我在學生會內都相當推薦大家學習（題外話，學生會會議紀錄為 HackMD、Trello 使用 Markdown、WordPress 站也使用 Markdown 編輯）。只要學一種語法就可以通吃，何樂不為呢？ 安裝 本篇文章以 Debian/Ubuntu 系統作為示範 方法一：使用 apt sudo apt install dokuwiki 安裝的同時會問你「要不要在在解除安裝時刪掉資料」，這就看大家了，我的話會選「不」，很怕某天手殘不小心刪掉... 再來他會告訴你資料都放在 /var/lib/dokuwiki 當中 然後．．．我就把他解除安裝了．．． 想到這路徑那麼奇怪，設定檔位置又不知道放哪邊還要看文件就覺得累，既然這個套件是 PHP 寫的，那我就抓下來放 /var/www 不就好啦～ 方法二：自行下載原始碼 下載連結 點開上面的網站後，選一下自己需要的語言以及外掛插件就可以直接按下載了。 下載後解壓縮放到你要的位置 tar xvf dokuwiki-*.tgz 再來就是設定檔啦～ Nginx 請點我 Apache 請點我 基本上複製貼上就會動了，這邊簡單說明一下設定檔（以 Nginx 為例） 我們可以看到裡面寫著： #Remember to comment the below out when you're installing, and uncomment it when done. location ~ /(data/|conf/|bin/|inc/|install.php) { deny all; } 意思是說請將 locati...
閱讀完整內容